Home

//Include library
#include  <Adafruit_GFX.h>
#include  <Adafruit_SSD1306.h>

#define OLED_RESET 4
Adafruit_SSD1306 display(OLED_RESET);

//Variables.
int cpuValue = 0;
String cpuValueString = "0";
String memValueString = "0";
String strArr[2]; //Set the size of the array to equal the number of values you will be receiveing.

void setup()
{
    //Initialize display by providing the diplay type and its I2C address.
    display.begin(SSD1306_SWITCHCAPVCC, 0x3C);

    //Start serial.
    Serial.begin(9600);
    Serial.println("Ready to display.");

    //Display setup.
    display.clearDisplay();
    display.setTextSize(1);
    display.setTextColor(WHITE);
}

void loop()
{
    String rxString = "";
	
    if (Serial.available()) {
        cpuValueString = "";

        //Keep looping until there is something in the buffer.
        while (Serial.available()) {
            //Delay to allow byte to arrive in input buffer.
            delay(2);
            //Read a single character from the buffer.
            char ch = Serial.read();
            //Append that single character to a string.
            rxString += ch;
        }

        int stringStart = 0;
        int arrayIndex = 0;

        for (int i = 0; i  < rxString.length(); i++) {
            //Get character and check if it's our "special" character.
            if (rxString.charAt(i) == ',') {
                //Clear previous values from array.
                strArr[arrayIndex] = "";

                //Save substring into array.
                strArr[arrayIndex] = rxString.substring(stringStart, i);
                //Set new string starting point.
                stringStart = (i + 1);
                arrayIndex++;
            }
        }

        //Put values from the array into the variables.
        cpuValueString = strArr[0];
        memValueString = strArr[1];

        //Convert string to int.
        cpuValue = cpuValueString.toInt();
    }

    //Clear display.
    display.clearDisplay();

    //CPU Text value display.
    display.setCursor(0, 5);
    display.print("CPU: " + cpuValueString + "%");

    //MEM Text value display.
    display.setCursor(0, 15);
    display.print("MEM: " + memValueString + " MB");

    //Progress bar display.
    //x,y,w,h
    display.drawRect(50, 5, 60, 5, WHITE);
    display.fillRect(50, 5, (cpuValue * 0.6), 5, WHITE);

    //Update display.
    display.display();
    delay(1);
}