Arduino SD Card Reader

DIY Arduino SD Card Reader
Share:

About

In this post, we’ll see how to make an SD card reader shield for the Arduino. It’s pretty simple as it’s just a matter of connecting the proper Arduino pins to the correct pads on the SD card adapter. Additionally, resistors need to be added for certain pins. These will form voltage dividers that will drop down the signal voltage for the SD card from 5V to around 3.3V.

Schematic

Software

This code will get the SD card info and send it over the serial port. In our case the CS is on pin 10 so I set the chipSelect variable to 10. You can find this code example:  File > Examples > SD > CardInfo 
/*
  SD card test

  This example shows how use the utility libraries on which the'
  SD library is based in order to get info about your SD card.
  Very useful for testing a card when you're not sure whether its working or not.

  The circuit:
    SD card attached to SPI bus as follows:
 ** MOSI - pin 11 on Arduino Uno/Duemilanove/Diecimila
 ** MISO - pin 12 on Arduino Uno/Duemilanove/Diecimila
 ** CLK - pin 13 on Arduino Uno/Duemilanove/Diecimila
 ** CS - depends on your SD card shield or module.
     Pin 4 used here for consistency with other Arduino examples


  created  28 Mar 2011
  by Limor Fried
  modified 9 Apr 2012
  by Tom Igoe
*/

// include the SD library:
#include <spi.h>
#include <sd.h>

// set up variables using the SD utility library functions:
Sd2Card card;
SdVolume volume;
SdFile root;

// change this to match your SD shield or module;
// Arduino Ethernet shield: pin 4
// Adafruit SD shields and modules: pin 10
// Sparkfun SD shield: pin 8
// MKRZero SD: SDCARD_SS_PIN
const int chipSelect = 10;

void setup() {
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }


  Serial.print("\nInitializing SD card...");

  // we'll use the initialization code from the utility libraries
  // since we're just testing if the card is working!
  if (!card.init(SPI_HALF_SPEED, chipSelect)) {
    Serial.println("initialization failed. Things to check:");
    Serial.println("* is a card inserted?");
    Serial.println("* is your wiring correct?");
    Serial.println("* did you change the chipSelect pin to match your shield or module?");
    while (1);
  } else {
    Serial.println("Wiring is correct and a card is present.");
  }

  // print the type of card
  Serial.println();
  Serial.print("Card type:         ");
  switch (card.type()) {
    case SD_CARD_TYPE_SD1:
      Serial.println("SD1");
      break;
    case SD_CARD_TYPE_SD2:
      Serial.println("SD2");
      break;
    case SD_CARD_TYPE_SDHC:
      Serial.println("SDHC");
      break;
    default:
      Serial.println("Unknown");
  }

  // Now we will try to open the 'volume'/'partition' - it should be FAT16 or FAT32
  if (!volume.init(card)) {
    Serial.println("Could not find FAT16/FAT32 partition.\nMake sure you've formatted the card");
    while (1);
  }

  Serial.print("Clusters:          ");
  Serial.println(volume.clusterCount());
  Serial.print("Blocks x Cluster:  ");
  Serial.println(volume.blocksPerCluster());

  Serial.print("Total Blocks:      ");
  Serial.println(volume.blocksPerCluster() * volume.clusterCount());
  Serial.println();

  // print the type and size of the first FAT-type volume
  uint32_t volumesize;
  Serial.print("Volume type is:    FAT");
  Serial.println(volume.fatType(), DEC);

  volumesize = volume.blocksPerCluster();    // clusters are collections of blocks
  volumesize *= volume.clusterCount();       // we'll have a lot of clusters
  volumesize /= 2;                           // SD card blocks are always 512 bytes (2 blocks are 1KB)
  Serial.print("Volume size (Kb):  ");
  Serial.println(volumesize);
  Serial.print("Volume size (Mb):  ");
  volumesize /= 1024;
  Serial.println(volumesize);
  Serial.print("Volume size (Gb):  ");
  Serial.println((float)volumesize / 1024.0);

  Serial.println("\nFiles found on the card (name, date and size in bytes): ");
  root.openRoot(volume);

  // list all files in the card with date and size
  root.ls(LS_R | LS_DATE | LS_SIZE);
}

void loop(void) {
}

Result:

This code example shows to read/write from/to the SD card.
//Includes ////////////////////////////////////////

#include <SPI.h>
#include <SD.h>

///////////////////////////////////////////////////


//Setup ///////////////////////////////////////////

//MOSI - pin 11 by default
//MISO - pin 12 by default
//CLK - pin 13 by default
//CS 
const int chipSelect = 10;

///////////////////////////////////////////////////


//Functions ///////////////////////////////////////

void readSD(char *fileName){
  //Open file.
  File file = SD.open(fileName);

  //If file is available ...
  if (file){
    Serial.println("File contents:");
  
    //Read file line by line until all lines are read.
    while (file.available()) {
      Serial.write(file.read()); //Print each line over serial.
    }
      
    //Close file.
    file.close();
  }else{
    Serial.println("File read failed.");
  }
}

void writeSD(char *fileName, char *data){
  File file = SD.open(fileName, FILE_WRITE);
  
  //If file is available ...
  if(file){
    //Write to file.
    file.println(data);
    //Close file.
    file.close();
  }else{
    Serial.println("File write failed.");
  }
}

/////////////////////////////////////////////////////


//Entry point ///////////////////////////////////////

void setup() {
  Serial.begin(9600);  

  if(SD.begin(chipSelect)) { //If SD card present...

    writeSD("test.txt", "Test text.");

    readSD("test.txt");
  }
  else
  {
    Serial.println("Unable to initilize SD card.");
  }
}

void loop() {

}

/////////////////////////////////////////////////////

Result:

Share:

Leave a Reply

Your email address will not be published. Required fields are marked *

The following GDPR rules must be read and accepted:
This form collects your name, email and content so that we can keep track of the comments placed on the website. For more info check our privacy policy where you will get more info on where, how and why we store your data.

Advertisment ad adsense adlogger