ESP32 Web Server, Web Sockets And HTTP API Calls

#include <SSD1306.h>
#include <ArduinoJson.h>
#include <WiFi.h>
#include <WebServer.h>
#include <WiFiManager.h>
#include "WebPage.h"


//Initialize /////////////////////////////////

//OLED display.
SSD1306 display(0x3c, 5, 4);

//Web server.
WebServer server(80);

//I/O pins.
int ledPin = 2;
int wifiSettingsResetPin = 14;

//Wifi AP ssid and password.
const char* ssid = "MyEspWebServerSetupAP";
const char* password = "";

///////////////////////////////////////////////


void setup()
{
  //Initialize display.
  display.init();
  display.flipScreenVertically();
  display.setFont(ArialMT_Plain_10);

  //Display initial AP connection info on the OLED screen.
  DisplayAPInfo(ssid, password, "/");

  //Open a serial port.
  Serial.begin(9600);

  //Print the AP info to the serial port.
  Serial.println("SSID: ");
  Serial.print(ssid);
  Serial.println("Password: ");
  Serial.print(password);

  //Initialize WiFiManager
  WiFiManager wm;
  if(digitalRead(wifiSettingsResetPin)) //If reset pin is HIGH.
    wm.resetSettings(); //Reset network settings.

  wm.setDebugOutput(false); //Disable debug info by default.

  //Create the initial AP used for setting the wifi configuration.
  bool response = wm.autoConnect(ssid, password);

  if (!response) {
    Serial.println("Failed to connect. Retrying connection ...");

    //Try again in 5s.
    ESP.restart();
    delay(5000);
  } else {
    Serial.println("Connected to wifi with IP: ");
    String ip = WiFi.localIP().toString();
    Serial.println(WiFi.localIP());

    DisplayAPInfo(ssid, password, ip);
  }

  //Set I/O.
  pinMode(ledPin, OUTPUT);

  //Initialize web server.
  initWebServer();
}

void loop(){
  server.handleClient();
}


inline void DisplayAPInfo(String ssid, String password, String ip) {
  display.clear();

  display.setTextAlignment(TEXT_ALIGN_LEFT);
  display.drawString(0, 0, "SSID: " + ssid);
  display.drawString(0, 10, "Pass: " + password); 
  display.drawString(0, 20, "IP: " + ip);

  display.display(); 
}


//////////////// Web Server ///////////////////

void initWebServer() {
  //Serve the HTML page to client when they go to the root path.
  server.on("/", HTTP_GET, serveInitialPage);

  //Setup other endpoints.
  server.on("/toggleLED", HTTP_GET, toggleLED);
  server.on("/readSensor", HTTP_POST, readSensor);

  //Start web server.
  server.begin();
}


void serveInitialPage() {
  server.send(200, "text/html", WEBPAGE);
}

void toggleLED() {
  if (server.hasArg("action")) {
    String action = server.arg("action");

    if (action == "1") {
      Serial.println("LED on");
      digitalWrite(ledPin, HIGH);
    }

    if (action == "0") {
      Serial.println("LED off");
      digitalWrite(ledPin, LOW);
    }
  }

  server.send(200, "text/plain", ""); //Send web page.
}

void readSensor() {
  //Get data from the body of the request.
  String requestBody = server.arg("plain");

  //Deserialize a json string.
  StaticJsonDocument<200> deserJsonDoc; //Set size of buffer to 200 bytes. For larger payloads DynamicJsonDocument(allocated on the heap) can be used.
  deserializeJson(deserJsonDoc, requestBody); //Desrialize json.
  const char* sensorID = deserJsonDoc["sensorID"]; //Get value from json document.



  //Read a sensor based on the sensor ID provided in the json.
  int sensorValue = 0;
  if(strcmp(sensorID, "sensor1") == 0){
    sensorValue = analogRead(A3); //GPIO 39
  } /*else if(strcmp(sensorID, "sensor2") == 0){ //add other sensors ...
    ...
  }*/
  


  //Serialize read value to a json string.
  StaticJsonDocument<200> serJsonDoc; //Set size of buffer to 200 bytes.
  serJsonDoc["value"] = sensorValue; //Set value.
  char jsonString[200]; //Make a json string variable.
  serializeJson(serJsonDoc, jsonString); //Serialize json.

  //Return read value as json.
  server.send(200, "application/json", jsonString); //Send web page
}

///////////////////////////////////////////////